home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Collection of Tools & Utilities
/
Collection of Tools and Utilities.iso
/
system
/
adapt12b.zip
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1993-11-24
|
7KB
|
215 lines
@IF "%ECHO%"=="" SET ECHO=OFF
@ECHO %ECHO%
REM VCS $Workfile: install.bat $
REM VCS $Revision: 1.2 $ $Date: 15 Oct 1993 22:42:14 $
REM VCS $Author: Abdenacer A. Moussaoui $
REM VCS $Logfile: A:/ADMIN.VCS/INSTALL.BAV $
REM INSTALL.BAT CREATED ON .1990/11/18│ .14:19:54│ BY UTIL
ECHO. [SA] install system
REM -- check if installation data is present
IF NOT EXIST ADAPT.DAT IF NOT EXIST ADAPT.EXE GOTO ERR1
REM -- check if enough env. space exists
SET X=123456789.123456789.123456789.123456789.
IF NOT "%X%"=="123456789.123456789.123456789.123456789." GOTO ERR0
SET X=
REM -- process command line
SET TD=%1
IF NOT "%TD%"=="" GOTO MAIN
REM IF NOT EXIST %TD%\U\*.* GOTO END
FOR %%P IN ( H h /H /c -H -h ) DO IF "%%P" == "%1" GOTO USAGE
:ASK
REM -- ask for installation target drive
CLS
ECHO "Welcome to ADAPT..."
ECHO If you have separate drives for data versus executables
ECHO We suggest you select the drive where you keep your data on.
DRIVEGET /T "Please select a target installation drive" /D E:
IF ERRORLEVEL 255 GOTO MSG1
CALL %TMP%\PARAMGET
rem set P1=%P1%.
rem postponed for later
rem CLS
rem PATHGET /T"Please select a valid target path" /D %P1% /P \
rem IF ERRORLEVEL 255 GOTO END
rem IF ERRORLEVEL 1 GOTO ERR3
rem CALL %TMP%\PARAMGET
SET TD=%P1%
REM -- verify with user
ECHO Yes > YNC.PKL
ECHO No >> YNC.PKL
ECHO Cancel >> YNC.PKL
REM PCK /$YN /T"Installing into [%TD%] Is this correct?"
PCK /1 /F YNC.PKL /T"Installing into [%TD%] Is this correct?"
IF ERRORLEVEL 255 GOTO MSG1
IF ERRORLEVEL 3 GOTO END
IF ERRORLEVEL 2 GOTO ASK
GOTO MAIN
REM -- Help Usage
:USAGE
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ Usage ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO.
ECHO %0 {options}
ECHO {installation-directory} install in the specified directory
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
GOTO END
:MAIN
rem -- test target directory is possible
rem MD %TD%
ECHO > %TD%\_TEST_
IF NOT EXIST %TD%\_TEST_ GOTO ERR2
DEL %TD%\_TEST_ > NUL
REM -- AUTOEXEC
REM --- create sample
ECHO REM -- BEGIN ADAPT > %TD%\_AUTO_.BAT
ECHO REM make sure your PATH is shortened to something like:>> %TD%\_AUTO_.BAT
ECHO REM PATH=C:\DOS;C:\WINDOWS;>> %TD%\_AUTO_.BAT
ECHO SET SYSD=%TD%>> %TD%\_AUTO_.BAT
ECHO CALL %TD%\U\RC\AUTOUBAT.BAT >> %TD%\_AUTO_.BAT
ECHO REM -- END ADAPT >> %TD%\_AUTO_.BAT
REM --- update
TYPE %TD%\_AUTO_.BAT >> C:\AUTOEXEC.BAT
REM -- CONFIG
REM --- create sample
ECHO REM -- BEGIN ADAPT > %TD%\_CONFIG_.SYS
ECHO REM create enough env. vars. space >> %TD%\_CONFIG_.SYS
ECHO SHELL=C:\COMMAND.COM /E:4096 /P>> %TD%\_CONFIG_.SYS
ECHO LASTDRIVE=Y>> %TD%\_CONFIG_.SYS
ECHO REM -- END ADAPT >> %TD%\_CONFIG_.SYS
REM --- update
TYPE %TD%\_CONFIG_.SYS >> C:\CONFIG.SYS
REM -- create some dirs
MD %TD%\USERS
MD %TD%\USERS\GUEST
MD %TD%\TMP
REM -- unlock files
IF EXIST %TD%\U\*.* ATTRIB -R %TD%\U\*.*
IF EXIST %TD%\U\RC\*.* ATTRIB -R %TD%\U\RC\*.*
IF EXIST %TD%\U\O\*.* ATTRIB -R %TD%\U\O\*.*
IF EXIST %TD%\L\*.* ATTRIB -R %TD%\L\*.*
REM -- install files
CLS
REN ADAPT.DAT ADAPT.EXE
ADAPT -X -D -O %TD%\ U\*.*
REM ADAPT0 -X -D -O %TD% U\RC\*.*
ADAPT -X -D -O %TD%\ L\*.*
ADAPT -X -D -O %TD%\ BIN\*.*
REN ADAPT.EXE ADAPT.DAT
COPY /B KWA.DAT+AIM.DAT %TD%\BIN\AIM.EXE
COPY /B KWA.DAT+HLPTOPIC.DAT %TD%\BIN\HLPTOPIC.EXE
COPY /B KWA.DAT+HLPFIND.DAT %TD%\BIN\HLPFIND.EXE
REM -- lock files
REM IF EXIST %TD%\U\*.* ATTRIB +R %TD%\U\*.*
REM IF EXIST %TD%\U\RC\*.* ATTRIB +R %TD%\U\RC\*.*
REM IF EXIST %TD%\U\O\*.* ATTRIB +R %TD%\U\O\*.*
REM IF EXIST %TD%\L\*.* ATTRIB +R %TD%\L\*.*
REM -- Install samples if targets not present
IF NOT EXIST %TD%\L\RC\AIM.DAT COPY %TD%\L\RC\SAMPLES\AIM.DAT %TD%\L\RC
IF NOT EXIST %TD%\L\RC\LOGIN.RC COPY %TD%\L\RC\SAMPLES\LOGIN.RC %TD%\L\RC
IF NOT EXIST %TD%\L\RC\SYSOP.MSG COPY %TD%\L\RC\SAMPLES\SYSOP.MSG %TD%\L\RC
IF NOT EXIST %TD%\L\RC\AUTOLBAT.BAT COPY %TD%\L\RC\SAMPLES\AUTOLBAT.BAT %TD%\L\RC
IF NOT EXIST %TD%\L\RC\MOTD COPY %TD%\L\RC\SAMPLES\MOTD %TD%\L\RC
REM -- add guest to user to database
SET L=%TD%\L
ECHO > %TD%\L\RC\TD.RC
%TD%\U\TD /START9
%TD%\U\TD "99|GUEST||%TD%\USERS\GUEST|default guest account" /R >> %TD%\L\RC\LOGIN.RC
CLS
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ ! ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO.
ECHO Installation completed.
ECHO.
ECHO (1)
ECHO Please verify the content of your
ECHO C:\AUTOEXEC.BAT see _AUTO_.BAT (appended)
ECHO C:\CONFIG.SYS see _CONFIG_.SYS (appended)
ECHO to ensure this system will be invoked during the next startup.
ECHO.
ECHO (2)
ECHO if you want to take advantage of the Application Information
ECHO Management system (AIM), you will need to revise \L\RC\AIM.DAT
ECHO.
ECHO Register to take full advantage of these software.
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
GOTO END
REM -- error messages
:ERR0
@ECHO OFF
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ ERROR ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO.
ECHO *** Cannot set environment variable in current space
ECHO Please adjust your config.sys line to smth like
ECHO SHELL=C:\OS2\COMMAND.COM /P /E:4096
ECHO You would need to reboot to make this take effect.
ECHO Then, retry operation.
ECHO.
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
PAUSE
GOTO USAGE
:ERR1
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ ERROR ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO Installation resource/data not found.
ECHO Make sure your are running installation from original disks
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
PAUSE
GOTO USAGE
:ERR2
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ ERROR ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO.
ECHO Cannot create target directory on [%TD%]
ECHO.
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
PAUSE
GOTO END
:ERR3
CALL %TMP%\PARAMGET
SET TD=%P1%
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ ERROR ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO.
ECHO Cannot create target directory [%TD%]
ECHO.
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
PAUSE
GOTO END
:MSG1
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒ ! ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
ECHO Installation was cancelled by user.
ECHO ▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒▒
:END